# SOME EXAMPLE QUERIES TO THE APERTIUM RDF GRAPH
# SPARQL ENDPOINT: http://linguistic.linkeddata.es/sparql
#
# by Jorge Gracia (UNIZAR)
# on December 2018

#-------------------------------------------------
# EXAMPLE 10
# Get all the direct translations belonging to a translation set:
# source and target written representations along with all the 
# intermediate elements and POS 

PREFIX lemon: <http://www.lemon-model.net/lemon#>
PREFIX tr: <http://purl.org/net/translation#>
PREFIX lexinfo: <http://www.lexinfo.net/ontology/2.0/lexinfo#>

SELECT DISTINCT ?written_rep_a ?lex_entry_a ?sense_a ?trans ?sense_b ?lex_entry_b ?written_rep_b ?POS
WHERE {
  
   
  #determine translation set
  ?trans_set lemon:language "en" ;
			 lemon:language "es" .
			 
  #retrieve translations
  ?trans_set tr:trans ?trans .
  
  #retrieve source and target senses
  ?trans tr:translationSource ?sense_a ;
		 tr:translationTarget ?sense_b .
    
  #retrieve source lexical entry, form and written representation
  ?sense_a lemon:isSenseOf  ?lex_entry_a .
  ?lex_entry_a lemon:lexicalForm ?form_a .
  ?form_a lemon:writtenRep ?written_rep_a .
  
  #retrieve target lexical entry, form and written representation
  ?sense_b lemon:isSenseOf  ?lex_entry_b .
  ?lex_entry_b lemon:lexicalForm ?form_b .
  ?form_b lemon:writtenRep ?written_rep_b .

  #retrieve POS
  ?lex_entry_b  lexinfo:partOfSpeech ?POS .
}